b87a4972c8
Set ZSH_AUTOSUGGEST_HISTORY_IGNORE to a glob pattern to have the history and match_prev_cmd suggestion strategies never make suggestions matching that pattern. For example, set to "cd *" to never suggest any `cd` commands from history (see issues #340 and #425). Or set to "?(#c50,)" to never suggest anything 50 characters or longer (see issue #429).
33 lines
1.2 KiB
Bash
33 lines
1.2 KiB
Bash
|
|
#--------------------------------------------------------------------#
|
|
# History Suggestion Strategy #
|
|
#--------------------------------------------------------------------#
|
|
# Suggests the most recent history item that matches the given
|
|
# prefix.
|
|
#
|
|
|
|
_zsh_autosuggest_strategy_history() {
|
|
# Reset options to defaults and enable LOCAL_OPTIONS
|
|
emulate -L zsh
|
|
|
|
# Enable globbing flags so that we can use (#m) and (x~y) glob operator
|
|
setopt EXTENDED_GLOB
|
|
|
|
# Escape backslashes and all of the glob operators so we can use
|
|
# this string as a pattern to search the $history associative array.
|
|
# - (#m) globbing flag enables setting references for match data
|
|
# TODO: Use (b) flag when we can drop support for zsh older than v5.0.8
|
|
local prefix="${1//(#m)[\\*?[\]<>()|^~#]/\\$MATCH}"
|
|
|
|
# Get the history items that match the prefix, excluding those that match
|
|
# the ignore pattern
|
|
local pattern="$prefix*"
|
|
if [[ -n $ZSH_AUTOSUGGEST_HISTORY_IGNORE ]]; then
|
|
pattern="($pattern)~($ZSH_AUTOSUGGEST_HISTORY_IGNORE)"
|
|
fi
|
|
|
|
# Give the first history item matching the pattern as the suggestion
|
|
# - (r) subscript flag makes the pattern match on values
|
|
typeset -g suggestion="${history[(r)$pattern]}"
|
|
}
|